*August 25, 2008
*Doc. ID: 64007, ECN S-81930, Rev. A
*File Name: Si7123DN_PS.txt and Si7123DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7123DN D G S
M1  3  GX S S PMOS W=5400000u L=0.25u 
M2  S  GX S D NMOS W=5400000u L=0.34u
RG  G  GX     2
R1  D  3      RTEMP 2E-3
CGS G  S      500E-12
DBD D  S      DBD
**************************************************************** 
.MODEL  PMOS         PMOS (LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 1.15E-3         RD     = 0           NSUB   = 2.6E16   
+ KP     = 4.5E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                 
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************** 
.MODEL  NMOS         NMOS (LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 8E16            IS     = 0		TPG    = -1)   
***************************************************************** 
.MODEL DBD D (CJO=230E-12 VJ=0.38 M=0.38
+FC=0.5 TT=1.88e-08 T_MEASURED=25 BV=21
+RS=8.247e-03 N=1.153 IS=6.007e-09 IKF=1000
+EG=7.997e-01 XTI=2.581 TRS1=7.410e-06)
***************************************************************** 
.MODEL RTEMP RES (TC1=12E-3 TC2=5.5E-6)
***************************************************************** 
.ENDS