*September 01, 2008
*Doc. ID: 64082, ECN S-82023, Rev. A
*File Name: Si8445DB_PS.txt and Si8445DB_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits. 
.SUBCKT Si8445DB D G S
M1  3  GX S S PMOS W=533358u L=0.25u   
M2  S  GX S D NMOS W=533358u L=0.46u  
RG  G  GX     5.5
R1  D  3      RTEMP 3E-2
CGS G  S      240E-12
DBD D  S      DBD
************************************************************* 
.MODEL  PMOS         PMOS (LEVEL  = 3         TOX    = 1.3E-8
+ RS     = 1.9E-2          RD     = 0         NSUB   = 1.2E15  
+ KP     = 9.3E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7      KAPPA  = 3E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                 
+ CGSO   = 0               CGDO   = 0         CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************** 
.MODEL  NMOS         NMOS (LEVEL  = 3         TOX    = 1.3E-8
+NSUB    = 1.2E17          IS     = 0         TPG    = -1)   
************************************************************** 
.MODEL DBD D (CJO=140E-12 VJ=0.38 M=0.31
+FC=0.5 TT=9.37e-09 T_MEASURED=25 BV=21
+RS=4.637e-02 N=2.265 IS=1.295e-05 IKF=1000
+EG=6.992e-01 XTI=6.561 TRS1=4.084e-09)
************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
************************************************************** 
.ENDS