*Jan 28, 2013
*ECN S13-0148, Rev. B
*File Name: SUM110N04-2m1P_PS.txt and SUM110N04-2m1P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet.  Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits. 
.SUBCKT SUM110N04-2m1P D G S
M1  3  GX S S NMOS W=29771256u L=0.250u      
M2  S  GX S D PMOS W=29771256u L=0.155u      
RG  G  GX     0.85
R1  D  3      RTEMP 8E-4
CGS GX S      14500E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 8.6E-4          RD     = 0           NSUB   = 2.7E17   
+ kp     = 1.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 3E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 5E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=4900E-12 VJ=0.38 M=0.39
+FC=0.5 TT=2.8e-08 T_MEASURED=25 BV=41
+RS=1.051e-03 N=1.065 IS=3.339e-11 IKF=1000
+EG=1.316 XTI=8.202e-02 TRS1=5.277e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
