*Mar 25, 2013
*ECN S13-0612, Rev. B
*File Name: SUD50N04-8m8P_PS.txt, SUD50N04-8m8P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT SUD50N04-8m8P D G S
M1  3  GX S S NMOS W=4154563u L=0.25u        
M2  S  GX S D PMOS W=4154563u L=0.21u     
RG  G  GX     5.5
R1  D  3      RTEMP 2.8E-3
CGS GX S      1730E-12
DBD S  D      DBD
******************************************************* 
.MODEL  NMOS     NMOS (LEVEL  = 3       TOX    = 5E-8
+ RS     = 3.8E-3      RD     = 0       NSUB   = 2.7E17  
+ KP     = 2E-5        UO     = 650             
+ VMAX   = 0           XJ     = 5E-7    KAPPA  = 3E-2
+ ETA    = 1E-4        TPG    = 1  
+ IS     = 0           LD     = 0            
+ CGSO   = 0           CGDO   = 0       CGBO   = 0 
+ NFS    = 0.8E12      DELTA  = 0.1)
********************************************************  
.MODEL  PMOS     PMOS (LEVEL  = 3       TOX    = 5E-8
+NSUB    = 2.6E16      IS     = 0       TPG    = -1)   
******************************************************** 
.MODEL DBD D (CJO=930E-12 VJ=0.38 M=0.42
+FC=0.5 TT=1.27E-8 T_MEASURED=25 BV=41
+RS=2.487e-03 N=1.083 IS=7.808e-12 IKF=1000  
+EG=1.171 XTI=1.771 TRS1=2.409e-03)
******************************************************** 
.MODEL RTEMP RES (TC1=11E-3 TC2=5.5E-6)
******************************************************** 
.ENDS 
