*January 21, 2008
*Doc. ID: 68161, S-80052, Rev. A
*File Name: Si4561DY_PS.txt and Si4561DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4561DY D1 G1 S1 D2 G2 S2 
X1 D1 G1 S1 Si4561N
X2 D2 G2 S2 Si4561P
.ENDS Si4561DY
*N-CH
.SUBCKT Si4561N D G S
M1  3  GX S S NMOS W=946643u L=0.25u  
M2  S  GX S D PMOS W=946643u L=0.34u   
RG  G  GX     2.2
R1  D  3      RTEMP 12E-3
CGS GX S      460E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 14.8E-3         RD     = 0           NSUB   = 2.58E17   
+ kp     = 1.7E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2.7E16          IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=160E-12 VJ=0.38 M=0.36
+FC=0.5 TT=1.69e-08 T_MEASURED=25 BV=41 
+RS=1.201e-02 N=1.114 IS=3.481e-12 IKF=1000
+EG=1.107 XTI=5.248 TRS1=3.268e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
****************************************************************  
.ENDS Si4561N
*P-CH
.SUBCKT Si4561P D G S
M1  3  GX S S PMOS W=3800000u L=0.25u                 
M2  S  GX S D NMOS W=3800000u L=0.38u    
RG  G  GX     3
R1  D  3      RTEMP 13E-3
CGS GX S      800E-12
DBD D  S      DBD
**************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 5E-8
+ RS     = 12E-3           RD     = 0          NSUB   = 9E16
+ KP     = 2.6E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 5E-8
+NSUB    = 2E16            IS     = 0          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=260E-12 VJ=0.38 M=0.44
+FC=0.5 TT=2.51e-08 T_MEASURED=25 BV=41
+RS=6.769e-03 N=1.531 IS=1.388e-08 IKF=1000
+EG=1.18 XTI=1.408 TRS1=3.207e-03))
*************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si4561P