*January 28, 2008
*Doc. ID: 68165, S-80153, Rev. A
*File Name: SUD50N04-07_PS.txt and SUD50N04-07_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUD50N04-07 D G S
M1  3  GX S S NMOS W=4625124u L=0.25u 
M2  S  GX S D PMOS W=4625124u L=0.50u
RG  G  GX     2
R1  D  3      RTEMP 38E-4
CGS GX S      1900E-12
DBD S  D      DBD
************************************************************** 
.MODEL  NMOS       NMOS  (LEVEL  = 3           TOX    = 5E-8
+ RS     = 15E-4          RD     = 0           NSUB   = 3E17  
+ KP     = 11E-6          UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 2E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS  (LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2E16           IS     = 0 	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=560E-12 VJ=0.38 M=0.33
+FC=0.5 TT=1.47e-08 T_MEASURED=25 BV=41 
+RS=1.887e-03 N=1.207 IS=1.383e-10 IKF=1000
+EG=1.225 XTI=5.410e-01 TRS1=2.955e-03 )
*************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS