*January 28, 2008
*Doc. ID: 68169, S-80150, Rev. A
*File Name: SUD50N03-06AP_PS.txt and SUD50N03-06AP_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.  
.SUBCKT SUD50N03-06AP D G S
M1  3  GX S S NMOS W=5515624u L=0.25u     
M2  S  GX S D PMOS W=5515624u L=0.32u    
RG  G  GX     0.90
R1  D  3      RTEMP 2E-3
CGS GX S      2680E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 2.2E-3          RD     = 0           NSUB   = 2.5E17   
+ kp     = 1.15E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 9E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 3E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=1200E-12 VJ=0.38 M=0.28 
+FC=0.5 TT=1.17e-08 T_MEASURED=25 BV=31 
+RS=2.723e-03 N=1.108 IS=2.369e-11 IKF=1000
+EG=1.191 XTI=1.119e-02 TRS1=8.935e-04 )
**************************************************************** 
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS