*Jan 28, 2013
*ECN S13-0189, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.  
.SUBCKT Si4654DY D G S
M1  3  GX S S NMOS W=5333200u L=0.25u     
M2  S  GX S D PMOS W=5333200u L=0.26u      
RG  G  GX     0.90
R1  D  3      RTEMP 1.4E-3
CGS GX S      2600E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 1.5E-3          RD     = 0           NSUB   = 2.9E17   
+ kp     = 1.8E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 3E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 3E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=1250E-12 VJ=0.38 M=0.32
+FC=0.5 TT=1.66e-08 TREF=25 BV=31 
+RS=2.071e-03 N=1.09 IS=2.434e-11 IK=1000
+EG=1.156 XTI=3.631e-01 TRS=6.429e-07 )
**************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
