*April 14, 2008
*Doc. ID: 68197, S-80744, Rev. A
*File Name: SiE850DF_PS.txt and SiE850DF_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.  
.SUBCKT SiE850DF D G S
M1  3  GX S S NMOS W=10253077u L=0.25u      
M2  S  GX S D PMOS W=10253077u L=0.10u     
RG  G  GX     0.65
R1  D  3      RTEMP 10.2E-4
CGS GX S      5800E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 8E-4            RD     = 0           NSUB   = 3.39E17   
+ kp     = 1.5E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 4E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2.7E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 3E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=2800E-12 VJ=0.38 M=0.38
+FC=0.5 TT=2.23e-08 T_MEASURED=25 BV=31 
+RS=4.667e-04 N=1.324 IS=3.963e-09 IKF=1000
+EG=7.579e-01 XTI=1.398e+01 TRS1=2.607e-06 )
**************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS