*April 14, 2008
*Doc. ID: 68201, S-80735, Rev. A
*File Name: Si3456CDV_PS.txt and Si3456CDV_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si3456CDV D G S
M1  3  GX S S NMOS W=677874u L=0.25u      
M2  S  GX S D PMOS W=67787u4 L=0.32u     
RG  G  GX     4.8
R1  D  3      RTEMP 13.5E-3
CGS GX S      330E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 11E-3          RD     = 0           NSUB   = 2.6E17  
+ KP     = 1E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5        TCV    = 4.5E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 3E16           IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=145E-12 VJ=0.38 M=0.27
+FC=0.5 TT=1.21E-8 T_MEASURED=25 BV=30.5
+RS=1.540e-02 N=1.197 IS=2.773e-11 IKF=1000  
+EG=1.189 XTI=1.384 TRS1=1.856e-03)
**************************************************************** 
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS