*March 24, 2008
*Doc. ID: 68252, S-80610, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits. 
.SUBCKT Si7194DP D G S
M1  3  GX S S NMOS W=10837062u L=0.25u       
M2  S  GX S D PMOS W=10837062u L=0.28u       
RG  G  GX     0.90
R1  D  3      RTEMP 6E-4
CGS GX S      4400E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 9E-4            RD     = 0           NSUB   = 2.7E17   
+ kp     = 2.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2.4E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 3E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=2600E-12 VJ=0.38 M=0.39
+FC=0.5 TT=2.1e-08 TREF=25 BV=26 
+RS=2.958e-03 N=1.045 IS=1.627e-11 IK=1000
+EG=1.141 XTI=1.826 TRS=1.427e-03 )
**************************************************************** 
.MODEL RTEMP R (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS