*August 25, 2008
*Doc. ID: 68423, S-81900, Rev. A
*File Name: Si4170DY_PS.txt and Si4170DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4170DY D G S
M1  3  GX S S NMOS W=7335817u L=0.25u        
M2  S  GX S D PMOS W=7335817u L=0.26u    
RG  G  GX     0.55
R1  D  3      RTEMP 12E-4
CGS GX S      3000E-12
DBD S  D      DBD
************************************************************  
.MODEL  NMOS       NMOS ( LEVEL  = 3         TOX    = 5E-8
+ RS     = 14E-4          RD     = 0         NSUB   = 2.92E17  
+ KP     = 1.96E-5        UO     = 650             
+ VMAX   = 0              XJ     = 5E-7      KAPPA  = 2E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0         CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
************************************************************  
.MODEL  PMOS       PMOS ( LEVEL  = 3         TOX    = 5E-8
+NSUB    = 2E16           IS     = 0         TPG    = -1)   
************************************************************ 
.MODEL DBD D (CJO=1700E-12 VJ=0.38 M=0.36
+FC=0.5 TT=1.71E-8 T_MEASURED=25 BV=31
+RS=1.188e-03 N=1.049 IS=4.573e-12 IKF=1000  
+EG=1.1 XTI=4.331 TRS1=11.821e-03)
************************************************************ 
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
************************************************************  
.ENDS