*Nov 12, 2012
*ECN S12-2713, Rev. B
*File Name: Si4459ADY_PS.txt, Si4459ADY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4459ADY D G S
M1  3  GX S S PMOS W=16258000u L=0.250u 
M2  S  GX S D NMOS W=16258000u L=0.372u
RG  G  GX     3
R1  D  3      RTEMP 1.4E-3
CGS G  S      2450E-12
DBD D  S      DBD
************************************************************** 
.MODEL  PMOS         PMOS (LEVEL  = 3         TOX    = 5E-8
+ RS     = 1.55E-3         RD     = 0         NSUB   = 1.1E17   
+ KP     = 2.3E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7      KAPPA  = 3E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                 
+ CGSO   = 0               CGDO   = 0         CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS         NMOS (LEVEL  = 3         TOX    = 5E-8
+NSUB    = 3E16            IS     = 0	      TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=580E-12 VJ=0.38 M=0.42
+FC=0.5 TT=2.31e-08 T_MEASURED=25 BV=31
+RS=1.467e-03 N=1.042 IS=1.182e-11 IKF=1000
+EG=1.179 XTI=1.923 TRS1=3.173e-03)
*************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS
