*September 01, 2008
*Doc. ID: 68567, ECN S-81936, Rev. A
*File Name: Si4626ADY_PS.txt and Si4626ADY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4626ADY D G S
M1  3  GX S S NMOS W=8515787u L=0.25u             
M2  S  GX S D PMOS W=8515787u L=0.28u           
RG  G  GX     0.95
R1  D  3      RTEMP 1.3E-3
CGS GX S      3720E-12
DBD S  D      DBD
******************************************************* 
.MODEL  NMOS     NMOS (LEVEL  = 3       TOX    = 5E-8
+ RS     = 1.2E-3      RD     = 0       NSUB   = 2.44E17  
+ KP     = 1.74E-5     UO     = 650             
+ VMAX   = 0           XJ     = 5E-7    KAPPA  = 1E-1
+ ETA    = 1E-4        TPG    = 1  
+ IS     = 0           LD     = 0            
+ CGSO   = 0           CGDO   = 0       CGBO   = 0 
+ NFS    = 0.8E12      DELTA  = 0.1)
*******************************************************  
.MODEL  PMOS     PMOS (LEVEL  = 3       TOX    = 5E-8
+NSUB    = 2.6E16      IS     = 0       TPG    = -1)   
******************************************************* 
.MODEL DBD D (CJO=1850E-12 VJ=0.38 M=0.41
+FC=0.5 TT=1.95E-8 T_MEASURED=25 BV=30.5
+RS=1.382e-03 N=1.049 IS=3.438e-12 IKF=1000  
+EG=1.2 XTI=2.683 TRS1=3.776e-03)
******************************************************* 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
******************************************************* 
.ENDS