*August 6, 2007
*Doc. ID: 69144, S-71614, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUP90N10-8m8P D G S
M1  3  GX S S NMOS W=14891313u L=0.25u   
M2  S  GX S D PMOS W=14891313u L=0.50u   
RG  G  GX     1.4
R1  D  3      RTEMP 2.7E-3
CGS GX S      4800E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 10E-8
+ RS     = 4E-3            RD     = 0           NSUB   = 2.4E17   
+ kp     = 8.7E-6          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 10E-8
+NSUB    = 3.5E15          IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=2500E-12 VJ=0.38 M=0.37   
+FC=0.5 TT=2.98E-8 TREF=25 BV=101 
+RS=1.410e-03 N=1.069 IS=1.148e-11 IK=1000
+EG=1.165 XTI=3.029 TRS=3.544e-03 )
**************************************************************** 
.MODEL RTEMP R (TC1=13E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS