*August 20, 2007
*Doc. ID: 69312, S-71712, Rev. A
*File Name: Si5857DU_PS.txt and Si5857DU_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt Si5857DU d g s a k
x1 d g s Si5857DU_mos
x2 a k   Si5857DU_schottky
.ends Si5857DU
.SUBCKT Si5857DU_mos D G S
M1  3  GX S S PMOS W=632128u L=0.25u            
M2  S  GX S D NMOS W=632128u L=0.45u 
RG  G  GX     9
R1  D  3      RTEMP 15E-3
CGS GX S      320E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 15E-3           RD     = 0          NSUB   = 4.5E16
+ KP     = 6.8E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 1E17            TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=75E-12 VJ=0.38 M=0.17
+RS=0.1 FC=0.5 IS=1E-12 TT=8.02E-9 N=1 BV=20.2)
*************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
*************************************************************** 
.ends Si5857DU_mos
.subckt Si5857DU_schottky 7 5
r1 7 1 5.71e-02 tc=1.33e-02,-1.06e-04
d1 1 5 sdsm
r2 7 2 4.52e-02 tc=1.14e-01,-2.75e-05
d2 2 5 sdlg
.model sdsm d (
+is=3.70e-07 n=6.74e-01 ikf=1 eg=5.76e-01
+xti=2e-01 
+bv=50 ibv=1e-1 )
.model sdlg d (
+is=2.36e-04 n=1.51 ikf=1 eg=2.19e-02
+xti=2.23e+1
+bv=50 ibv=1e-1 
+vj=0.386 cjo=290e-12 m=0.302)
.ends Si5857DU_schottky