*January 21, 2008
*Doc. ID: 69323, S-80011, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt  Si5856DC d g s a k
x1 d g s Si5856DC_mos
x2 a k   Si5856DC_schottky
.ends Si5856DC
.SUBCKT Si5856DC_mos D G S
M1  3  G S S NMOS W=485249u L=0.50u       
M2  S  G S D PMOS W=485249u L=0.35u  
R1  D  3     RTEMP 14E-3
CGS G  S     170E-12
DBD S  D     DBD
*****************************************************************  
.MODEL  NMOS        NMOS ( LEVEL  = 3            TOX    = 1.7E-8
+ RS     = 14E-3           RD     = 0		 NSUB   = 2.05E17      
+ KP     = 13E-5           UO     = 650 
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 5E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5         TCV    = 1.45E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
****************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3            TOX    = 1.7E-8
+NSUB    = 7E16            TPG    = -1)           
 ***************************************************************** 
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.28
+RS=0.1 FC=0.1 IS=1E-12 TT=5E-8 N=1 BV=20.2)
****************************************************************** 
.MODEL RTEMP R (TC1=6E-3 TC2=5.5E-6)
****************************************************************** 
.ENDS Si5856DC_mos
.subckt Si5856DC_schottky 7 5
r1 7 1 5.71e-02 tc=1.33e-02,-1.06e-04
d1 1 5 sdsm
r2 7 2 4.52e-02 tc=1.14e-01,-2.75e-05
d2 2 5 sdlg
.model sdsm d (
+is=3.70e-07 n=6.74e-01 ik=1 eg=5.76e-01
+xti=2e-01 
+bv=50 ibv=1e-1 )
.model sdlg d (
+is=2.36e-04 n=1.51 ik=1 eg=2.19e-02
+xti=2.23e+1
+bv=50 ibv=1e-1 
+vj=0.386 cjo=290e-12 m=0.302)
.ends Si5856DC_schottky