*September 3, 2007
*Doc. ID: 69344, S-71801, Rev. A
*File Name: SUD50N10-34P_PS.txt and SUD50N10-34P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUD50N10-34P D G S
M1  3  GX S S NMOS W=3036751u L=0.50u 
M2  S  GX S D PMOS W=3036751u L=0.35u
RG  G  GX     1.2
R1  D  3      RTEMP 21E-3
CGS GX S      940E-12
DBD S  D      DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 7E-8
+ RS     = 6E-3            RD     = 0               NSUB   = 2.2E17   
+ kp     = 4.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 150E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 7E-8
+NSUB    = 1.15E16         TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=830e-12 VJ=0.38 M=0.40 
+FC=0.1 IS=1E-12 TT=4.57E-8 N=1 BV=101)
*************************************************************************
.MODEL RTEMP RES (TC1=7.5E-3 TC2=5.5E-6)
*************************************************************************
.ENDS