*October 8, 2007
*Doc. ID: 69400, S-72035, Rev. A
*File Name: Si7326DN_PS.txt and Si7326DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7326DN D G S
M1  3  GX S S  NMOS W=1031898u L=0.25u      
M2  S  GX S D  PMOS W=1031898u L=0.70u  
RG  G  GX      1.4 
R1  D  3       RTEMP 2E-3
CGS GX S       520E-12
DBD S  D       DBD
******************************************************************* 
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 6.5E-8
+ RS     = 9.5E-3          RD     = 0               NSUB   = 1.1E17
+ KP     = 0.81E-5         U0     = 650
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 85E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
******************************************************************* 
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 6.5E-8
+NSUB    = 5E16            IS     = 0               TPG    = -1)           
 ****************************************************************** 
.MODEL DBD D (CJO=200E-12 VJ=0.38 M=0.30
+FC=0.5 TT=1.81e-08 T_MEASURED=25 BV=31 
+RS=4.489e-03 N=1.406 IS=1.363e-09 IKF=1000
+EG=1.060 XTI=7.046e-03 TRS1=7.015e-04 )
******************************************************************* 
.MODEL RTEMP RES (TC1=15E-3 TC2=5.5E-6)
******************************************************************* 
.ENDS