*October 8, 2007
*Doc. ID: 69420, S-72073, Rev. A
*File Name: SUP90N08-8m2P_PS.txt and SUP90N08-8m2P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUP90N08-8m2P D G S
M1  3  GX S S NMOS W=8812987u L=0.25u  
M2  S  GX S D PMOS W=8812987u L=0.52u
RG  G  GX     1.8
R1  D  3      RTEMP 26E-4
CGS GX S      2500E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 10E-8
+ RS     = 23E-4          RD     = 0            NSUB   = 2.12E17 
+ KP     = 4E-6           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 3E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 10E-8
+NSUB    = 6E15           IS	 = 0		TPG    = -1)   
****************************************************************  
.MODEL DBD D (CJO=2400E-12 VJ=0.38 M=0.42
+FC=0.5 TT=2.72e-08 T_MEASURED=25 BV=76 
+RS=1.973e-03 N=1.034 IS=4.050e-12 IKF=1000
+EG=1.192 XTI=1.74 TRS1=3.232e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS