*October 8, 2007
*Doc. ID: 69432, S-72076, Rev. A
*File Name: SQ9945AEY_PS.txt and SQ9945AEY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SQ9945AEY D G S                              
M1  3  G S S NMOS W=434200u L=0.30u
M2  S  G S D PMOS W=434200u L=0.90u
R1  D  3     RTEMP 44E-3
CGS G  S     420E-12
DBD S  D     DBD
************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 16E-3          RD     = 0           NSUB   = 1.9E17  
+ kp     = 1.97E-5        UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 3E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                         
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 1.8E16         IS     = 0 	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=240E-12 VJ=0.38 M=0.30
+FC=0.5 TT=3.81e-08 T_MEASURED=25 BV=61 
+RS=1.330e-02 N=1.372 IS=1.084e-09 IKF=1000
+EG=1.356 XTI=9.012e-08 TRS1=3.291e-03 )
***************************************************************
.MODEL RTEMP RES (TC1=7E-3 TC2=6.5E-6)
****************************************************************
.ENDS