*January 21, 2008
*Doc. ID: 69435, S-80054, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt  si4642dy d g s
x1 d g s si4642dy_mos
x2 s d   si4642dy_schottky
.ends si4642dy
.SUBCKT Si4642DY_mos D G S
M1  3  GX S S NMOS W=8493121u L=0.25u  
M2  S  GX S D PMOS W=8493121u L=0.30u  
RG  G  GX     1.5
R1  D  3      RTEMP 1E-3
CGS GX S      3900E-12
*************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 1.6E-3         RD     = 0            NSUB   = 1.6E17 
+ KP     = 8E-6           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5         TCV    = 4E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 3E16           IS     = 0		TPG    = -1)   
*************************************************************** 
.MODEL RTEMP R (TC1=10E-3 TC2=5.5E-6)
*************************************************************** 
.ends si4642dy_mos 
.subckt si4642dy_schottky 7 5
d1 7 5 sdsm
d2 7 5 sdlg
d3 7 4 sdrev
d4 5 4 sdblk
.model sdsm d (is=1.149e-11 n=1.101 eg=1.072 xti=7.580 
+rs=1.612e-03 trs=2.914e-03)
.model sdlg d (is=1.229e-05 n=1.149 eg=6.414e-01 xti=7.627e-01
+rs=4.118e-02 trs=6.462e-03  
+vj=0.38 cjo=1700e-12 m=0.34)
.model sdrev d (is=2.8e-5 n=1.449 eg=1.829e-01 xti=2.492e+01)
.model sdblk d (is=1e-11 n=1)
.ends si4642dy_schottky