*Nov 12, 2012
*ECN S12-2710, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si4102DY D G S
M1  3  GX S S NMOS W=631560u L=0.50u 
M2  S  GX S D PMOS W=631560u L=0.40u 
RG  G  GX     3
R1  D  3      RTEMP 120E-3  
CGS GX S      230E-12
DBD S  D      DBD
************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 7E-8
+ RS     = 22E-3           RD     = 0           NSUB   = 2E17  
+ kp     = 3.3E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 150E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 4.3E-3
+ NFS    = 0.6E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 7E-8
+NSUB    = 0.8E16          IS	  = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=186e-12 VJ=0.38 M=0.38 
+FC=0.5 TT=4.34e-08 TREF=25 BV=102 
+RS=1.721e-02 N=1.282 IS=1.141e-10 IK=1000
+EG=1.203 XTI=1.149 TRS=5.752e-04 )
**************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
 
