*October 29, 2007
*Doc. ID: 69448, S-72189, Rev. A
*File Name: Si1300BDL_PS.txt and Si1300BDL_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si1300BDL D G S
M1  3  GX S S NMOS W=17473u L=0.25u    
M2  S  GX S D PMOS W=17473u L=0.45u 
RG  G  GX     7
R1  D  3      RTEMP 2.4E-1
CGS GX S      26E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 1.75E-8
+ RS     = 3E-1           RD     = 0            NSUB   = 2.3E17 
+ KP     = 2.7E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 3E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 1.75E-8
+NSUB    = 9E16           IS	 = 0		TPG    = -1)   
****************************************************************  
.MODEL DBD D (CJO=20E-12 VJ=0.38 M=0.18
+FC=0.5 TT=2e-08 T_MEASURED=25 BV=21 
+RS=4.000e-01 N=1.343 IS=1.061e-13 IKF=1000
+EG=1.041 XTI=4.866 TRS1=1.090e-05  )
**************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS