*Dec 03, 2012
*ECN S12-2846, Rev. B
*File Name: Si5424DC_PS.txt, Si5424DC_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5424DC D G S
M1  3  GX S S NMOS W=1753632u L=0.25u  
M2  S  GX S D PMOS W=1753632u L=0.50u  
RG  G  GX     2.2
R1  D  3      RTEMP 10.5E-3
CGS GX S      740E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 6.5E-8
+ RS     = 6E-3            RD     = 0           NSUB   = 1.4E17   
+ kp     = 9E-6            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 6.5E-8
+NSUB    = 9E16            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=130E-12 VJ=0.38 M=0.23
+FC=0.1 IS=1E-12 TT=9.2E-9 N=1 BV=30.2)
**************************************************************** 
.MODEL RTEMP RES (TC1=5.5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
 
