*March 3, 2008
*Doc. ID: 69691, S-80400, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiB411DK D G S
M1  3  GX S S PMOS W=429650u L=0.25u             
M2  S  GX S D NMOS W=429650u L=0.48u 
RG  G  GX     7.5
R1  D  3      RTEMP 2E-2
CGS GX S      200E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 1.7E-8
+ RS     = 2E-2            RD     = 0          NSUB   = 2E16
+ KP     = 1.1E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5       TCV    = 1.9E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 1.7E-8
+NSUB    = 9E16            IS     = 0 	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=70E-12 VJ=0.38 M=0.18
+FC=0.5 TT=1.01e-08 TREF=25 BV=21 
+RS=1.794e-02 N=2.065 IS=1.271e-06 IK=1000
+EG=9.109e-01 XTI=5.138 TRS=1.063e-06 )
*************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS