*November 19, 2007
*Doc. ID: 69704, S-72403, Rev. A
*File Name: Si3850ADV_PS.txt and Si3850ADV_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si3850ADV D G1 S1 G2 S2 
X1 D G1 S1 Si3850N
X2 D G2 S2 Si3850P
.ENDS Si3850ADV
*N-CH
.SUBCKT Si3850N D G S
M1  3  GX S S NMOS W=47210u L=0.25u    
M2  S  GX S D PMOS W=47210u L=0.92u 
RG  G  GX     3.5  
R1  D  3      RTEMP 7E-2
CGS GX S      50E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 3E-8
+ RS     = 8.7E-2         RD     = 0            NSUB   = 1.96E17  
+ KP     = 2E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 1E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 3E-8
+NSUB    = 1.6E17         IS	 = 0            TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=42E-12 VJ=0.38 M=0.18
+FC=0.5 TT=1.13e-08 T_MEASURED=25 BV=20.2 
+RS=7.85E-02 N=1.51E+00 IS=1.51E-09 IKF=1000
+EG=9.95E-01 XTI=2.57E+00 TRS1=1.42E-07 )
**************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
****************************************************************  
.ENDS Si3850N
*P-CH
.SUBCKT Si3850P D G S
M1  3  GX S S PMOS W=47210u L=0.25u                
M2  S  GX S D NMOS W=47210u L=0.85u  
RG  G  GX     10.5
R1  D  3      RTEMP 17E-2
CGS GX S      65E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 13E-2           RD     = 0          NSUB   = 5E16
+ KP     = 8.2E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 1.2E17          IS     = 0          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=50E-12 VJ=0.38 M=0.19
+FC=0.5 TT=8.44e-09 T_MEASURED=25 BV=21 
+RS=3.255e-01 N=1.419 IS=5.694e-10 IKF=1000
+EG=6.704e-01 XTI=1.326e+01 TRS1=2.811e-12 )
*************************************************************** 
.MODEL RTEMP RES (TC1=8E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si3850P