*March 3, 2008
*Doc. ID: 69707, S-80404, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt  Si7160DP d g s
x1 d g s Si7160DP_mos
x2 s d   Si7160DP_schottky
.ends Si7160DP
.SUBCKT Si7160DP_mos D G S
M1  3  GX S S NMOS W=4666550u L=0.25u     
M2  S  GX S D PMOS W=4666550u L=0.25u     
RG  G  GX     1
R1  D  3      RTEMP 3.2E-3
CGS GX S      1900E-12
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 3.8E-3         RD     = 0           NSUB   = 3.2E17  
+ KP     = 1.8E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 3E-3
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0            
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5        TCV    = 3.5E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 3E16           IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL RTEMP R (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si7160DP_mos
.subckt Si7160dp_schottky 7 5
d1 7 5 sdsm
d2 7 5 sdlg
d3 7 4 sdrev
d4 5 4 sdblk
.model sdsm d (is=1.562e-11 n=1.139 eg=1.185 xti=2.827 
+rs=3.983e-3 trs=2.685e-3)
.model sdlg d (is=4.019e-5 n=1.111 eg=0.6179 xti=8.1e-4
+rs=2.522e-2 trs=4.606e-3
+vj=0.38 cjo=1500e-12 m=0.40)
.model sdrev d (is=1.34e-4 n=2.139 eg=8.73e-2 xti=33.4)
.model sdblk d (is=1e-11 n=1)
.ends si7160dp_schottky