*January 21, 2008
*Doc. ID: 69712, S-80015, Rev. A
*File Name: Si3879DV_PS.txt and Si3879DV_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.  
.subckt Si3879DV d g s a  
x1 d g s Si3879DV_mos
x2 a d   Si3879DV_schottky
.ends Si3879DV
.SUBCKT Si3879DV_mos D G S
M1  3  GX S S PMOS W=547478u L=0.25u              
M2  S  GX S D NMOS W=547478u L=0.30u  
RG  G  GX     7.5
R1  D  3      RTEMP 23E-3
CGS GX S      326E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 15E-3           RD     = 0          NSUB   = 5.5E16
+ KP     = 9.5E-6          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 8E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 8E16            IS     = 0          TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=215E-12 VJ=0.38 M=0.26
+FC=0.5 TT=9.07E-9 T_MEASURED=25 BV=22
+RS=1.868e-02 N=1.153 IS=2.615e-11 IKF=1000
+EG=1.201 XTI=2.330e-01 TRS1=1.825e-03)
*************************************************************** 
.MODEL RTEMP RES (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si3879DV_mos
.subckt Si3879DV_schottky 7 5
r1 7 1 7.97e-02 tc=2.32e-02,-1.52e-04
d1 1 5 sdsm
r2 7 2 1.05 tc=0.6,1.96e-02
d2 2 5 sdlg
.model sdsm d (
+is=1.81e-06 n=9.32e-01 ikf=1 eg=6.23e-01
+xti=2.19e-01 
+bv=50 ibv=1e-1 )
.model sdlg d (
+is=1.95e-05 n=1.61 ikf=1 eg=4.9e-01
+xti=10
+bv=50 ibv=1e-1 
+vj=0.233 cjo=261e-12 m=0.393)
.ends Si3879DV_schottky