*January 21, 2008
*Doc. ID: 69715, S-80013, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits. 
.subckt  Si4396DY d g s
x1 d g s Si4396DY_mos
x2 s d   Si4396DY_schottky
.ends Si4396DY
.SUBCKT Si4396DY_mos D G S
M1  3  GX S S NMOS W=2368350u L=0.25u  
M2  S  GX S D PMOS W=2368350u L=0.35u 
RG  G  GX     1.55
R1  D  3      RTEMP 5E-3
CGS GX S      1200E-12
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 5E-8
+ RS     = 3.7E-3         RD     = 0            NSUB   = 2.67E17  
+ KP     = 1.2E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 5E-3
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5         TCV    = 4E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 5E-8
+NSUB    = 5E16           IS     = 0            TPG    = -1)   
**************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si4396DY_mos
.subckt Si4396DY_schottky 7 5
d1 7 5 sdsm
d2 7 5 sdlg
d3 7 4 sdrev
d4 5 4 sdblk
.model sdsm d (is=1.000e-09 n=1.357 eg=1.078 xti=6.322 
+rs=5.207e-03 trs=2.685e-3)
.model sdlg d (is=7.418e-05 n=1.111 eg=6.077e-01 xti=5.498e-01
+rs=2.144e-02 trs=4.606e-3 BV=30
+vj=0.38 cjo=1100e-12 m=0.37)
.model sdrev d (is=1e-4 n=3.659 eg=2.120 xti=1.000e-01)
.model sdblk d (is=1e-11 n=1)
.ends Si4396DY_schottky