*January 21, 2008
*Doc. ID: 69863, S-80051, Rev. A
*File Name: Si4636DY_PS.txt and Si4636DY_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.subckt  Si4636DY d g s
x1 d g s Si4636DY_mos
x2 s d   Si4636DY_schottky
.ends Si4636DY
.SUBCKT Si4636DY_mos D G S
M1  3  GX S S NMOS W=3930568u L=0.25u  
M2  S  GX S D PMOS W=3930568u L=0.22u
RG  G  GX     1.3
R1  D  3      RTEMP 3E-3
CGS GX S      1800E-12
**************************************************************** 
.MODEL  NMOS       NMOS ( LEVEL  = 3            TOX    = 4E-8
+ RS     = 3.2E-3         RD     = 0            NSUB   = 3.5E17 
+ KP     = 2E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7         KAPPA  = 3E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0               
+ CGSO   = 0              CGDO   = 0            CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS       PMOS ( LEVEL  = 3            TOX    = 4E-8
+NSUB    = 3E16           IS	 = 0		TPG    = -1)   
****************************************************************  
.MODEL RTEMP RES (TC1=9E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS Si4636DY_mos
.subckt Si4636DY_schottky 7 5
d1 7 5 sdsm
d2 7 5 sdlg
d3 7 4 sdrev
d4 5 4 sdblk
.model sdsm d (is=5.653e-11 n=1.194 eg=1.224 xti=7.310e-01 
+rs=3.467e-03 trs1=2.142e-03)
.model sdlg d (is=5.621e-05 n=1.121 eg=5.953e-01 xti=1.769e-02
+rs=2.735e-02 trs1=4.226e-03
+vj=0.38 cjo=1800e-12 m=0.47)
.model sdrev d (is=1e-4 n=1.77 eg=1.000e-01 xti=2.928e+01)
.model sdblk d (is=1e-11 n=1)
.ends Si4636DY_schottky