*Feb 04, 2013
*ECN S13-0236, Rev. B
*File Name: Si5410DU_PS.txt, Si5410DU_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product datasheet. Designers should refer to the
*appropriate datasheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5410DU D G S
M1  3  GX S S NMOS W=2165279u L=0.25u  
M2  S  GX S D PMOS W=2165279u L=0.24u   
RG  G  GX     3.5
R1  D  3      RTEMP 7E-3
CGS GX S      950E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 6.7E-3          RD     = 0           NSUB   = 2.99E17   
+ kp     = 2E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 2E16            IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=470E-12 VJ=0.38 M=0.40
+FC=0.5 TT=1.77e-08 T_MEASURED=25 BV=41 
+RS=8.656e-03 N=1.241 IS=8.964e-11 IKF=1000
+EG=1.256 XTI=7.779e-02 TRS1=3.583e-03 )
**************************************************************** 
.MODEL RTEMP RES (TC1=6.5E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS
 
