*July 16, 2007 
*Doc. ID: 73925, S-71391, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits. 
.SUBCKT Si4662DY D G S
M1  3  GX S S NMOS W=2259076u L=0.25u    
M2  S  GX S D PMOS W=2259076u L=0.30u    
RG  G  GX     1.9
R1  D  3      RTEMP 2E-3
CGS GX S      1100E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 4.9E-3          RD     = 0           NSUB   = 2.2E17   
+ kp     = 1.28E-5         UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 6E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 4.5E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 5E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=550E-12 VJ=0.38 M=0.22 
+FC=0.5 TT=1.53e-08 TREF=25 BV=30.2 
+RS=5.860e-03 N=1.158 IS=1.306e-10 IK=1000
+EG=1.113 XTI=3.312e-01 TRS=8.985e-06 )
**************************************************************** 
.MODEL RTEMP R (TC1=13E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS