*July 16, 2007
*Doc. ID: 73934, S-71388, Rev. A
*File Name: SiA413DJ_PS.txt and SiA413DJ_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiA413DJ D G S
M1  3  GX S S PMOS W=2348000u L=0.25u           
M2  S  GX S D NMOS W=2348000u L=0.35u
RG  G  GX     7
R1  D  3      RTEMP 10E-3
CGS GX S      240E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 12.8E-3         RD     = 0           NSUB   = 2E16
+ KP     = 1E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 1.8E17          IS     = 0		TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=160E-12 VJ=0.38 M=0.26
+FC=0.5 TT=1e-08 T_MEASURED=25 BV=12.2 
+RS=1.243e-02 N=1.419 IS=9.998e-08 IKF=1000
+EG=9.188e-01 XTI=3.501e-01 TRS1=1.426e-06 )
*************************************************************** 
.MODEL RTEMP RES (TC1=4E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS