*July 16, 2007
*Doc. ID: 73945, S-71469, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiA513DJ D1 G1 S1 D2 G2 S2 
X1 D1 G1 S1 SiA513N
X2 D2 G2 S2 SiA513P
.ENDS SiA513DJ
*N-CH
.SUBCKT SiA513N D G S
M1  3  GX S S NMOS W=361042u L=0.25u    
M2  S  GX S D PMOS W=361042u L=0.40u    
RG  G  GX     2.5
R1  D  3      RTEMP 20E-3
CGS GX S      350E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 18E-3           RD     = 0           NSUB   = 1.34E17   
+ kp     = 2E-5            UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3.66E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 8E16            IS     = 0		TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=50E-12 VJ=0.38 M=0.20 
+FC=0.5 TT=1.37e-08 TREF=25 BV=20.2 
+RS=1.608e-02 N=1.098 IS=1.000e-11 IK=1000
+EG=1.002 XTI=3.012 TRS=3.649e-03 )
**************************************************************** 
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
****************************************************************  
.ENDS SiA513N
*P-CH
.SUBCKT SiA513P D G S
M1  3  GX  S S PMOS W=325941u L=0.25u           
M2  S  GX  S D NMOS W=325941u L=0.35u
RG  G  GX      8
R1  D  3       RTEMP 35E-3
CGS GX S       160E-12
DBD D  S       DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 30E-3           RD     = 0           NSUB   = 5E16
+ KP     = 9E-6            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2.8E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 1.6E17          IS     = 0		TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=60E-12 VJ=0.38 M=0.20
+FC=0.5 TT=1.03e-08 TREF=25 BV=21 
+RS=1.895e-02 N=1.232 IS=3.671e-11 IK=1000
+EG=1.212 XTI=1.967e-01 TRS=3.401e-03 )
*************************************************************** 
.MODEL RTEMP R (TC1=7E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS SiA513P