*May 14, 2007
*Doc. ID: 74704, S-70977, Rev. A
*File Name: SiB413DK_PS.txt and SiB413DK_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SiB413DK D G S
M1  3  GX S S PMOS W=480022u L=0.25u            
M2  S  GX S D NMOS W=480022u L=0.40u
RG  G  GX     8.1
R1  D  3      RTEMP 2E-2
CGS GX S      210E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3          TOX    = 3E-8
+ RS     = 3E-2            RD     = 0          NSUB   = 8.5E16
+ KP     = 1.1E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7       KAPPA  = 5E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0          CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3          TOX    = 3E-8
+NSUB    = 1E17            IS     = 0 	       TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=90E-12 VJ=0.38 M=0.24
+FC=0.5 TT=7.93e-09 T_MEASURED=25 BV=21 
+RS=1.442e-02 N=1.156 IS=1.000e-11 IKF=1000
+EG=1.221 XTI=1.625e-01 TRS1=1.677e-03 )
*************************************************************** 
.MODEL RTEMP RES (TC1=8.5E-3 TC2=5.5E-6)
***************************************************************  
.ENDS