*July 30, 2007
*Doc. ID: 74747, S-71399, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si5905BDC D G S
M1  3  GX S S PMOS W=273593u L=0.25u           
M2  S  GX S D NMOS W=273593u L=0.40u
RG  G  GX     5.5
R1  D  3      RTEMP 2.6E-2
CGS GX S      190E-12
DBD D  S      DBD
***************************************************************  
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 1.7E-8
+ RS     = 1.3E-2          RD     = 0           NSUB   = 4E15
+ KP     = 1E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 5E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2.1E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 1.7E-8
+NSUB    = 3E17            IS     = 0		TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=120E-12 VJ=0.38 M=0.30
+FC=0.5 TT=9.22e-09 TREF=25 BV=21 
+RS=1.711e-02 N=1.773 IS=1.000e-07 IK=1000
+EG=1.125 XTI=1.242e-01 TRS=3.564e-04 )
*************************************************************** 
.MODEL RTEMP R (TC1=6E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS