*May 14, 2007
*Doc. ID: 74759, S-70955, Rev. A
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUU_SUD50N04-16P D G S
M1  3  GX S S NMOS W=2273616u L=0.25u   
M2  S  GX S D PMOS W=2273616u L=0.25u   
RG  G  GX     2.1
R1  D  3      RTEMP 5E-3
CGS GX S      1600E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 4E-8
+ RS     = 6.8E-3          RD     = 0           NSUB   = 2.26E17   
+ kp     = 1.8E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 3.3E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 4E-8
+NSUB    = 8E16            IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=350E-12 VJ=0.38 M=0.30   
+FC=0.5 TT=1.76E-8 TREF=25 BV=41 
+RS=6.198e-03 N=1.194 IS=2.022e-10 IK=1000
+EG=8.190e-01 XTI=1.000e+01 TRS=2.574e-05 )
**************************************************************** 
.MODEL RTEMP R (TC1=11E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS