*May 14, 2007
*Doc. ID: 74772, S-70962, Rev. A
*File Name: Si7236DP_PS.txt and Si7236DP_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7236DP D G S
M1  3  GX S S NMOS W=5733190u L=0.25u  
M2  S  GX S D PMOS W=5733190u L=0.20u  
RG  G  GX     3.5
R1  D  3      RTEMP 1E-3
CGS GX S      2800E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 3E-8
+ RS     = 2.8E-3          RD     = 0           NSUB   = 2.75E17   
+ kp     = 3.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 8E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 3E-8
+NSUB    = 3.5E16          IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=1150E-12 VJ=0.38 M=0.29   
+FC=0.5 TT=1.5E-8 T_MEASURED=25 BV=21 
+RS=2.223e-03 N=1.319 IS=7.957e-09 IKF=1000
+EG=1.064 XTI=1.140 TRS1=8.196e-08 )
**************************************************************** 
.MODEL RTEMP RES (TC1=13E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS