*May 14, 2007
*Doc. ID: 74937, S-70979, Rev. A
*File Name: SUD50N025-4m5P_PS.txt and SUD50N025-4m5P_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUD50N025-4m5P D G S
M1  3  GX S S NMOS W=7389252u L=0.25u  
M2  S  GX S D PMOS W=7389252u L=0.25u  
RG  G  GX     1.05
R1  D  3      RTEMP 14.3E-4
CGS GX S      3800E-12
DBD S  D      DBD
**************************************************************** 
.MODEL  NMOS        NMOS ( LEVEL  = 3           TOX    = 5E-8
+ RS     = 15E-4           RD     = 0           NSUB   = 2.5E17   
+ kp     = 8.7E-6          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 1E-3
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
**************************************************************** 
.MODEL  PMOS        PMOS ( LEVEL  = 3           TOX    = 5E-8
+NSUB    = 9E16            IS     = 0           TPG    = -1)   
**************************************************************** 
.MODEL DBD D (CJO=1700E-12 VJ=0.38 M=0.28   
+FC=0.5 TT=1.22E-8 T_MEASURED=25 BV=26 
+RS=2.987e-03 N=1.05 IS=1.597e-11 IKF=1000
+EG=1.152 XTI=1.408 TRS1=1.852e-04 )
**************************************************************** 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)
**************************************************************** 
.ENDS