*Feb 20, 2006
*Doc. ID: 75003, S-60244, Rev. B
*File Name: Si7909DN_PS.txt and Si7909DN_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Si7909DN 4 1 2
M1  3 1 2 2 PMOS W=1037085u L=0.50u  
M2  2 1 2 4 NMOS W=1037085u L=0.90u
R1  4 3     RTEMP 3.2E-3
CGS 1 2     20E-12
DBD 4 2     DBD
*****************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 21E-3           RD     = 0             NSUB   = 1.2E16   
+ KP     = 2.5E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 30E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                     
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 1.8E17          TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=290E-12 VJ=0.38 M=0.30
+RS=0.1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=12.2)
*****************************************************************
.MODEL RTEMP RES (TC1=10E-3 TC2=5.5E-6)
*****************************************************************
.ENDS