*Feb. 28, 2005
*Doc. ID: 75007, S-50232, Rev. B
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si1553DL 6 2 1 3 5 4  
X1 6 2 1 Si1553N
X2 3 5 4 Si1553P
.ENDS Si1553DL
*N-Ch
.SUBCKT Si1553N 4 1 2   
M1  3 1 2 2 NMOS W=26939u L=0.5u 
M2  2 1 2 4 PMOS W=26939u L=1.5u  
R1  4 3     RTEMP 1300E-4
CGS 1 2     40E-12
DBD 2 4     DBD
**************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3          TOX    = 3E-8
+ RS     = 830E-4         RD     = 0          NSUB   = 1.3E17  
+ KP     = 5E-5           UO     = 650             
+ VMAX   = 0              XJ     = 5E-7       KAPPA  = 2E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0          CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5       TCV    = 2.55E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
**************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3          TOX    = 3E-8
+NSUB    = 4.5E16         TPG    = -1)   
**************************************************************
.MODEL DBD D (CJO=30E-12 VJ=0.38 M=0.30
+RS=2.5  FC=0.5 IS=1E-12 TT=14E-8 N=1 BV=21)
**************************************************************
.MODEL RTEMP R (TC1=7.5E-3  TC2=5.5E-6)
**************************************************************
.ENDS Si1553N
*P-Ch
.SUBCKT Si1553P 4 1 2  
M1  3 1 2 2 PMOS W=40408u L=0.70u
M2  2 1 2 4 NMOS W=40408u L=0.70u  
R1  4 3     RTEMP 240E-3
CGS 1 2     65E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 3E-8
+ RS     = 330E-3          RD     = 0               NSUB   = 0.94E16   
+ KP     = 2E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 40E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                   
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5            TCV    = 2.15E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 3E-8
+NSUB    = 4E16             NFS   = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=28E-12 VJ=0.38 M=0.30
+RS=4 FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=30.2)
*************************************************************************
.MODEL RTEMP R (TC1=8E-3 TC2=5.5E-6)
*************************************************************************
.ENDS Si1553P