*Nov 21, 2005
*Doc. ID: 75018, S-52393, Rev. C
*File Name: Si1563EDH_PS.txt and Si1563EDH_PS.lib
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si1563EDH 6 2 1 3 5 4  
X1 6 2 1 Si1563N
X2 3 5 4 Si1563P
.ENDS Si1563EDH
************************************************************
*N-CHANNEL
.SUBCKT Si1563N 4 1 2   
M1    3 5 2 2 NMOS W=55269u L=0.50u
M2    2 5 2 4 PMOS W=55269u L=0.70u
R1    4 3     RTEMP 95E-3 
CGS   5 2     50E-12
DBD   2 4     DBD
XESDN 1 5 2   ESD_Si1563N
************************************************************  
.MODEL  NMOS         NMOS (LEVEL  = 3       TOX    = 1.7E-8
+ RS     = 70E-3           RD     = 0       NSUB   = 1.63E17   
+ KP     = 5.2E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7    KAPPA  = 10E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0       CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
************************************************************  
.MODEL  PMOS          PMOS (LEVEL = 3       TOX    = 1.7E-8
+NSUB    = 2.7E16          TPG    = -1)   
************************************************************  
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.30
+RS=1 FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=20.5) 
.MODEL RTEMP RES (TC1=6E-3 TC2=5.5E-6)  
.ENDS Si1563N
************************************************************
*P-CHANNEL
.SUBCKT Si1563P 4 1 2
M1    3 5 2 2 PMOS W=55269u L=0.5u
M2    2 5 2 4 NMOS W=55269u L=0.9u
R1    4 3     RTEMP 150E-3  
CGS   5 2     45E-12
DBD   4 2     DBD
XESDP 1 5 2   ESD_Si1563P
************************************************************ 
.MODEL  PMOS        PMOS ( LEVEL  = 3        TOX    = 1.7E-8
+ RS     = 100E-3          RD     = 0        NSUB   = 0.8E15   
+ KP     = 1.6E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7     KAPPA  = 1E-4
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                       
+ CGSO   = 0               CGDO   = 0        CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
************************************************************ 
.MODEL  NMOS        NMOS ( LEVEL  = 3        TOX    = 1.7E-8
+NSUB    = 7E16            TPG    = 1)   
************************************************************ 
.MODEL DBD D (CJO=40E-12 VJ=0.38 M=0.33
+RS=1 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.2)
.MODEL RTEMP RES (TC1=5.8E-3 TC2=5.5E-6)
.ENDS Si1563P
************************************************************ 
*ESD FOR N-CHANNEL
.SUBCKT ESD_Si1563N 1 5 2
rd7 1 9 4K 
d7 9 2 dleak  
.MODEL dleak d (IS=3e-9 XTI=450 EG=1.17 T_MEASURED=25 TBV1=0 N=42 BV=6.4) 
rd3 1 10 105 TC=-0.002
d3 11 10 dout 1.422
d4 11 12 dout 1.422
d5 13 12 dout 1.78
d6 13  2 dout 1.78
.MODEL dout D (IS=1E-10 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-1.07e-3 N=2.5 BV=6.05)
rpoly 1 5 1.35K TC=0.0015
rd8 5 14 1 
d8 15 14 din 
d9 15 2 din  
.MODEL din D (IS=3E-10 XTI=-20 EG=1.17 T_MEASURED=25 TBV1=-2.48e-4 N=2.2 BV=6.05)
.ENDS ESD_Si1563N
******************************************************************
*ESD FOR P-CHANNEL
.SUBCKT ESD_Si1563P 1 5 2
rd7 1 9 10K 
d7 9 2 dleak  
.MODEL dleak d (IS=3e-9 XTI=360 EG=1.17 T_MEASURED=25 TBV1=0 N=39 BV=6.4) 
rd3 1 10 105 TC=-0.002
d3 11 10 dout 1.422
d4 11 12 dout 1.422
d5 13 12 dout 1.78
d6 13  2 dout 1.78
.MODEL dout D (IS=1E-10 XTI=-35 EG=1.17 T_MEASURED=25 TBV1=-1.16e-3 N=2.5 BV=6.05)
rpoly 1 5 4.1K TC=0.001
rd8 5 14 1 
d8 15 14 din  
d9 15 2 din  
.MODEL din D (IS=5E-10 XTI=-20 EG=1.17 T_MEASURED=25 TBV1=1.54e-4 N=1.5 BV=6.48)
.ENDS ESD_Si1563P
*******************************************************************