*May 16, 2005
*Doc. ID: 75024, S-50836, Rev. B
*File Name: Si3588DV_PS.txt and Si3588DV_PS.lib
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si3588DV 6 2 1 3 5 4  
X1 6 2 1 Si3588N
X2 3 5 4 Si3588P
.ENDS Si3588DV
*N-Ch
.SUBCKT Si3588N 4 1 2   
M1  3 1 2 2 NMOS W=206176u L=0.50u 
M2  2 1 2 4 PMOS W=206176u L=0.75u
R1  4 3     RTEMP 29E-3
CGS 1 2     200E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 1.7E-8
+ RS     = 9E-3            RD     = 0               NSUB   = 1.55E17   
+ KP     = 3.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 3E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 1.7E-8
+NSUB    = 8E16            TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=80E-12 VJ=0.38 M=0.38
+FC=0.5 IS=1E-12 TT=5E-8 N=1 BV=21)
*************************************************************************
.MODEL RTEMP RES (TC1=5E-3 TC2=5.5E-6)
*************************************************************************
.ENDS Si3588N
*P-Ch
.SUBCKT Si3588P 4 1 2   
M1  3 1 2 2 PMOS W=206176u L=0.50u
M2  2 1 2 4 NMOS W=206176u L=1.50u
R1  4 3     RTEMP 39E-3
CGS 1 2     180E-12
DBD 4 2     DBD
*****************************************************************
.MODEL  PMOS         PMOS (LEVEL  = 3             TOX    = 1.7E-8
+ RS     = 48E-3           RD     = 0             NSUB   = 2.4E15   
+ KP     = 2.2E-5          UO     = 400             
+ VMAX   = 0               XJ     = 5E-7          KAPPA  = 2E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12	   DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS         NMOS (LEVEL  = 3             TOX    = 1.7E-8
+NSUB    = 1.2E16          TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=150E-12 VJ=0.38 M=0.38
+RS=0.05 FC=0.5 IS=1E-12 TT=6.7E-8 N=1 BV=20.5)
*****************************************************************
.MODEL RTEMP RES (TC1=7.8E-3 TC2=5.5E-6)
*****************************************************************
.ENDS Si3588P