*Jan 2, 2006
*Doc. ID: 75039, S-52575, Rev. B
*File Name: Si4532ADY_PS.txt and Si4532ADY_PS.lib
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si4532ADY 6 2 1 3 5 4 
X1 6 2 1 Si4532N 
X2 3 5 4 Si4532P 
.ENDS Si4532ADY
*N-Ch
.SUBCKT Si4532N 4 1 2   
M1  3 1 2 2 NMOS W=467935u L=0.50u
M2  2 1 2 4 PMOS W=467935u L=0.67u
R1  4 3     RTEMP 25E-3
CGS 1 2     260E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS         NMOS (LEVEL  = 3               TOX    = 5E-8
+ RS     = 11.5E-3         RD     = 0               NSUB   = 1.6E17   
+ kp     = 2.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 12E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS         PMOS (LEVEL  = 3               TOX    = 5E-8
+NSUB    = 2.5E16          TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=180E-12 VJ=.38 M=0.3
+FC=0.1 IS=1E-12 TT=7.6E-8 N=1 BV=30.5)
*************************************************************************
.MODEL RTEMP RES (TC1=5.8E-3 TC2=5.5E-6)
*************************************************************************
.ENDS Si4532N
*P-Ch
.SUBCKT Si4532P 4 1 2
M1  3 1 2 2 PMOS W=399328u L=0.5u 
M2  2 1 2 4 NMOS W=399328u L=1.0u 
R1  4 3     RTEMP 34E-3
CGS 1 2     420E-12
DBD 4 2     DBD
**************************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3               TOX    = 5E-8
+ RS     = 22E-3           RD     = 0               NSUB   = 7.95E16   
+ KP     = 1.15E-5         UO     = 400             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 40E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                           
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 5E-8
+NSUB    = 4E16            NFS    = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=200E-12 VJ=0.38 M=0.31
+RS=0.2 FC=0.5 IS=1E-10 TT=15E-8 N=1 BV=31)
*************************************************************************
.MODEL RTEMP RES (TC1=7.8E-3 TC2=5.5E-6)
*************************************************************************
.ENDS Si4532P