*Jan 2, 2006
*Doc. ID: 75054, S-52575, Rev. B
*File Name: Si4562DY_PS.txt and Si4562DY_PS.lib
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si4562DY 6 2 1 3 5 4  
X1 6 2 1 Si4562N
X2 3 5 4 Si4562P
.ENDS Si4562DY
*N-CH
.SUBCKT Si4562N 4 1 2   
M1  3 1 2 2 NMOS W=1492226u L=0.5u
M2  2 1 2 4 PMOS W=1492226u L=0.9u
R1  4 3     RTEMP 10.5E-3
CGS 1 2     1700E-12
DBD 2 4     DBD
****************************************************************** 
.MODEL  NMOS       NMOS  (LEVEL  = 3               TOX    = 3E-8
+ RS     = 58E-4          RD     = 0               NSUB   = 1.7E17  
+ kp     = 4.4E-5         UO     = 650             
+ VMAX   = 0              XJ     = 5E-7            KAPPA  = 5E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                           
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12         DELTA  = 0.1)
******************************************************************
.MODEL  PMOS        PMOS (LEVEL  = 3               TOX    = 3.8E-8
+NSUB    = 4.2E16         TPG    = -1)   
****************************************************************** 
.MODEL DBD D (CJO=1000E-12 VJ=0.38 M=0.35 
+FC=0.5 IS=1E-12 TT=3.3E-8 N=1 BV=40)
****************************************************************** 
.MODEL RTEMP RES (TC1=4.1E-3 TC2=6.5E-6)
****************************************************************** 
.ENDS Si4562N
*P-CH
.SUBCKT Si4562P 4 1 2   
M1  3 1 2 2 PMOS W=1492226u L=0.5u 
M2  2 1 2 4 NMOS W=1492226u L=0.8u
R1  4 3     RTEMP 1.05E-2
CGS 1 2     2200E-12
DBD 4 2     DBD
******************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3             TOX    = 3E-8
+ RS     = 1.25E-2         RD     = 0             NSUB   = 2.05E16   
+ kp     = 1.50E-5         UO     = 400             
+ VMAX   = 0               XJ     = 0.5E-6        KAPPA  = 10.8E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                            
+ CGSO   = 0               CGDO   = 0             CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
****************************************************************** 
.MODEL  NMOS       NMOS (  LEVEL  = 3             TOX    = 3.6E-8
+NSUB    = 2.8E16          NFS    = 10E11         TPG    = -1)   
****************************************************************** 
.MODEL DBD D (CJO=900E-12 VJ=0.38 M=0.33
+RS=0.1 FC=0.5 IS=1E-12 TT=7.5E-8 N=1 BV=40)
****************************************************************** 
.MODEL RTEMP RES (TC1=7.1E-3 TC2=8.5E-6)
******************************************************************
.ENDS Si4562P