*Jan 23, 2006
*Doc. ID: 75055, S-60074, Rev. B
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si5513DC 6 2 1 3 5 4  
X1 6 2 1 Si5513N
X2 3 5 4 Si5513P
.ENDS Si5513DC 
*N-CH
.SUBCKT Si5513N 4 1 2   
M1  3 1 2 2 NMOS W=194914u L=0.50u
M2  2 1 2 4 PMOS W=194914u L=0.95u
R1  4 3     RTEMP 260E-4
CGS 1 2     240E-12
DBD 2 4     DBD
***************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3           TOX    = 3E-8
+ RS     = 180E-4         RD     = 0           NSUB   = 1.57E17  
+ kp     = 3.97E-5        UO     = 650             
+ VMAX   = 0              XJ     = 5E-7        KAPPA  = 1E-1
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                          
+ CGSO   = 0              CGDO   = 0           CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5        TCV    = 2.8E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
***************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3           TOX    = 3E-8
+NSUB    = 5E16           TPG    = -1)   
*************************************************************** 
.MODEL DBD D (CJO=130E-12 VJ=0.38 M=0.31
+RS=1 FC=0.5 IS=1E-12 TT=17E-8 N=1 BV=40)
*************************************************************** 
.MODEL RTEMP R (TC1=6.5E-3 TC2=5.5E-6)
*************************************************************** 
.ENDS Si5513N
*P-CH
.SUBCKT Si5513P 4 1 2    
M1  3 1 2 2 PMOS W=183649u L=0.50u 
M2  2 1 2 4 NMOS W=183649u L=0.85u  
R1  4 3     RTEMP 40E-3
CGS 1 2     260E-12
DBD 4 2     DBD
***************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3           TOX    = 3E-8
+ RS     = 52E-3           RD     = 0           NSUB   = 1.4E16
+ KP     = 2E-5            UO     = 400            
+ VMAX   = 0               XJ     = 5E-7        KAPPA  = 20E-3
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                       
+ CGSO   = 0               CGDO   = 0           CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5        TCV    = 2.2E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
***************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3           TOX    = 3E-8
+NSUB    = 4E16            NFS    = 10E11       TPG    = -1)   
***************************************************************
.MODEL DBD D (CJO=110E-12 VJ=0.38 M=0.31
+RS=0.6 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=20.5)
****************************************************************
.MODEL RTEMP R (TC1=7.5E-3 TC2=5.5E-6)
****************************************************************
.ENDS Si5513P
 
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.