*Feb 13, 2006
*Doc. ID: 75058, S-60146, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
*Dn Gn Sn Dp Gp Sp
.SUBCKT Si6562DQ 6 2 1 3 5 4  
X1 6 2 1 Si6562N
X2 3 5 4 Si6562P
.ENDS Si6562DQ
*N-CH  
.SUBCKT Si6562N 4 1 2                             
M1  3 1 2 2 NMOS W=828290u L=0.3u
M2  2 1 2 4 PMOS W=828290u L=0.8u
R1  4 3     RTEMP 10E-3
CGS 1 2     10.7E-10
DBD 2 4     DBD
*******************************************************************
.MODEL  NMOS         NMOS (LEVEL = 3               TOX    = 3E-8
+ RS     = 9.2E-3         RD     = 0               NSUB   = 2.05E17  
+ kp     = 3.99E-5        UO     = 650             
+ VMAX   = 0              XJ     = 0.5E-6          KAPPA  = 0.5E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                          
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ TLEV   = 1              BEX    = -1.5            TCV    = 2.55E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*******************************************************************
.MODEL  PMOS         PMOS (LEVEL = 3               TOX    = 3.8E-8
+NSUB    = 11E16          TPG    = -1)   
*******************************************************************
.MODEL DBD D (CJO=4.2E-10 VJ=0.38 M=0.30
+FC=0.5 IS=1E-12 TT=8.4E-8 N=1 BV=40)
*******************************************************************
.MODEL RTEMP R (TC1=6E-3 TC2=6.5E-6)
*******************************************************************
.ENDS Si6562N
*P-CH
.SUBCKT Si6562P 4 1 2   
M1  3 1 2 2 PMOS W=402268u L=0.50u 
M2  2 1 2 4 NMOS W=402268u L=2.25u
R1  4 3     RTEMP 15E-3
CGS 1 2     1800E-12
DBD 4 2     DBD
******************************************************************
.MODEL  PMOS       PMOS (  LEVEL  = 3            TOX    = 3E-8
+ RS     = 15E-3           RD     = 0            NSUB   = 1.65E16   
+ KP     = 4E-5            UO     = 400             
+ VMAX   = 0               XJ     = 5E-7         KAPPA  = 2.1E-2
+ ETA    = 1E-4            TPG    = -1  
+ IS     = 0               LD     = 0                        
+ CGSO   = 0               CGDO   = 0            CGBO   = 0 
+ TLEV   = 1               BEX    = -1.5         TCV    = 2.25E-3
+ NFS    = 0.8E12          DELTA  = 0.1)
*****************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3            TOX    = 3E-8
+NSUB    = 3E16            TPG    = 1)   
*****************************************************************
.MODEL DBD D (CJO=600E-12 VJ=0.38 M=0.36
+RS=0.2 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=21)
*****************************************************************
.MODEL RTEMP R (TC1=7E-3 TC2=8E-6)
*****************************************************************
.ENDS Si6562P