*October 30, 2006
*Doc. ID: 75094, S-62152, Rev. B
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT SUPB70N06-14 4 1 2
M1  3 1 2 2 NMOS W=2834920u L=0.5u 
M2  2 1 2 4 PMOS W=2834920u L=1.1u
R1  4 3     RTEMP 7E-3
CGS 1 2     1660E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS  (LEVEL  = 3               TOX    = 7E-8
+ RS     = 6.2E-3         RD     = 0               NSUB   = 1.8E17  
+ kp     = 5E-5           UO     = 400             
+ VMAX   = 0              XJ     = 5E-7            KAPPA  = 10E-2
+ ETA    = 1E-4           TPG    = 1  
+ IS     = 0              LD     = 0                              
+ CGSO   = 0              CGDO   = 0               CGBO   = 0 
+ TLEV   = 1              BEX    = -1.6            TCV    = 4.2E-3
+ NFS    = 0.8E12         DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL   = 3               TOX    = 7E-8
+NSUB    = 5E15           NFS    = 10E11           TPG    = -1)   
*************************************************************************
.MODEL DBD D (CJO=1800E-12 VJ=0.38    M=0.38 
+RS=0.1 FC=0.5 IS=1E-12 TT=6E-8 N=1 BV=60.5)
*************************************************************************
.MODEL RTEMP R (TC1=7.5E-3 TC2=5.5E-6)
*************************************************************************
.ENDS