*March 20, 2006
*Doc. ID: 75136, S-60409, Rev. B
*File Name: SUD35N05-26L_PS.txt and SUD35N05-26L_PS.lib
*This document is intended as a SPICE modeling guideline and does not
*constitute a commercial product data sheet.  Designers should refer to the
*appropriate data sheet of the same number for guaranteed specification
*limits.
.SUBCKT Sud35n05-26L 4 1 2
M1  3 1 2 2 NMOS W=1699949u L=0.50u 
M2  2 1 2 4 PMOS W=1699949u L=0.75u
R1  4 3     RTEMP 10E-3
CGS 1 2     470E-12
DBD 2 4     DBD
**************************************************************************
.MODEL  NMOS       NMOS (  LEVEL  = 3               TOX    = 7E-8
+ RS     = 6E-3            RD     = 0               NSUB   = 1E17   
+ kp     = 2.6E-5          UO     = 650             
+ VMAX   = 0               XJ     = 5E-7            KAPPA  = 2E-2
+ ETA    = 1E-4            TPG    = 1  
+ IS     = 0               LD     = 0                             
+ CGSO   = 0               CGDO   = 0               CGBO   = 0 
+ NFS    = 0.8E12          DELTA  = 0.1)
*************************************************************************
.MODEL  PMOS       PMOS (LEVEL    = 3               TOX    = 7E-8
+NSUB    = 1E16            TPG    = -1)           
*************************************************************************
.MODEL DBD D (CJO=560E-12  VJ=.38   M=0.39
+RS=0.1 FC=0.1 IS=1E-12 TT=4E-8 N=1 BV=55.5)
*************************************************************************
.MODEL RTEMP RES (TC1=8E-3   TC2=5.5E-6)
*************************************************************************
.ENDS